[Experiment] DIY Robotic 2 wheel drive car using L298N motor driver and NodeMCU | ESP 8266

 DIY 2 Wheel drive robotic car

In this experiment we will learn building 2 wheel drive robotic car using 2wd kit and L298N motor driver. We will use Websockets to control this car from mobile browser. 



Lets first start building the car.

Components needed

1. 2WD car kit
    a. Chassis
    b. 2 BO motor with soldered wires
    c. 2 BO Wheels
    d. Screws, nuts and spacers
    e. Mounting accessories
    f. 12V Battery pack. You can use battery pack provided by kit
    g. Front ball wheel
2. L298N motor driver



3. Jumper wires, DC female jack adaptor wire.
4. NodeMCU

Connections

NodeMCU    L298N driver

        D2                    IN1    
        D5                    IN2
        D6                    IN3
        D7                    IN4
        Vcc                    5V
        G                      Gnd

Got to Library Manager and search Websockets.



Code

/*
 * This ESP8266 NodeMCU code was developed by newbiely.com
 *
 * This ESP8266 NodeMCU code is made available for public use without any restriction
 *
 */

#include <ESP8266WiFi.h>
#include <ESP8266WebServer.h>
#include <WebSocketsServer.h>
#include "index.h"

#define CMD_STOP 0
#define CMD_FORWARD 1
#define CMD_BACKWARD 2
#define CMD_LEFT 4
#define CMD_RIGHT 8


#define IN1_PIN D2  // The ESP8266 pin connected to the IN1 pin L298N
#define IN2_PIN D5  // The ESP8266 pin connected to the IN2 pin L298N
#define IN3_PIN D6  // The ESP8266 pin connected to the IN3 pin L298N
#define IN4_PIN D7  // The ESP8266 pin connected to the IN4 pin L298N


const char* ssid = "Your SSID";     // CHANGE IT
const char* password = "Your Password";  // CHANGE IT

ESP8266WebServer server(80);                        // Web server on port 80
WebSocketsServer webSocket = WebSocketsServer(81);  // WebSocket server on port 81

void webSocketEvent(uint8_t num, WStype_t type, uint8_t* payload, size_t length) {
  switch (type) {
    case WStype_DISCONNECTED:
      Serial.printf("[%u] Disconnected!\n", num);
      break;
    case WStype_CONNECTED:
      {
        IPAddress ip = webSocket.remoteIP(num);
        Serial.printf("[%u] Connected from %d.%d.%d.%d\n", num, ip[0], ip[1], ip[2], ip[3]);
      }
      break;
    case WStype_TEXT:
      //Serial.printf("[%u] Received text: %s\n", num, payload);
      String angle = String((char*)payload);
      int command = angle.toInt();
      Serial.print("command: ");
      Serial.println(command);

      switch (command) {
        case CMD_STOP:
          Serial.println("Stop");
          CAR_stop();
          break;
        case CMD_FORWARD:
          Serial.println("Move Forward");
          CAR_moveForward();
          break;
        case CMD_BACKWARD:
          Serial.println("Move Backward");
          CAR_moveBackward();
          break;
        case CMD_LEFT:
          Serial.println("Turn Left");
          CAR_turnLeft();
          break;
        case CMD_RIGHT:
          Serial.println("Turn Right");
          CAR_turnRight();
          break;
        default:
          Serial.println("Unknown command");
      }

      break;
  }
}

void setup() {
  Serial.begin(9600);

  pinMode(IN1_PIN, OUTPUT);
  pinMode(IN2_PIN, OUTPUT);
  pinMode(IN3_PIN, OUTPUT);
  pinMode(IN4_PIN, OUTPUT);

  // Connect to Wi-Fi
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi...");
  }
  Serial.println("Connected to WiFi");

  // Initialize WebSocket server
  webSocket.begin();
  webSocket.onEvent(webSocketEvent);

  // Serve a basic HTML page with JavaScript to create the WebSocket connection
  server.on("/", HTTP_GET, []() {
    Serial.println("Web Server: received a web page request");
    String html = HTML_CONTENT; 
    server.send(200, "text/html", html);
  });

  server.begin();
  Serial.print("ESP8266 Web Server's IP address: ");
  Serial.println(WiFi.localIP());
}

void loop() {
  // Handle client requests
  server.handleClient();

  // Handle WebSocket events
  webSocket.loop();

}

void CAR_moveForward() {
  digitalWrite(IN1_PIN, HIGH);
  digitalWrite(IN2_PIN, LOW);
  digitalWrite(IN3_PIN, HIGH);
  digitalWrite(IN4_PIN, LOW);
}

void CAR_moveBackward() {
  digitalWrite(IN1_PIN, LOW);
  digitalWrite(IN2_PIN, HIGH);
  digitalWrite(IN3_PIN, LOW);
  digitalWrite(IN4_PIN, HIGH);
}

void CAR_turnLeft() {
  digitalWrite(IN1_PIN, HIGH);
  digitalWrite(IN2_PIN, LOW);
  digitalWrite(IN3_PIN, LOW);
  digitalWrite(IN4_PIN, LOW);
}

void CAR_turnRight() {
  digitalWrite(IN1_PIN, LOW);
  digitalWrite(IN2_PIN, LOW);
  digitalWrite(IN3_PIN, HIGH);
  digitalWrite(IN4_PIN, LOW);
}

void CAR_stop() {
  digitalWrite(IN1_PIN, LOW);
  digitalWrite(IN2_PIN, LOW);
  digitalWrite(IN3_PIN, LOW);
  digitalWrite(IN4_PIN, LOW);
}



Now open new tab from top right corner of current sketch
create a new file called index.h
/*
 * This ESP8266 NodeMCU code was developed by newbiely.com
 *
 * This ESP8266 NodeMCU code is made available for public use without any restriction
 */

const char *HTML_CONTENT = R"=====(
<!DOCTYPE html>
<html>
<head>
<title>ESP8266 Control Car via Web</title>
<meta name="viewport" content="width=device-width, initial-scale=0.7, maximum-scale=1, user-scalable=no">
<style type="text/css">
body { text-align: center; font-size: 24px;}
button { text-align: center; font-size: 24px;}
#container {
    margin-right: auto;
    margin-left: auto;
  width: 400px; 
    height: 400px;
    position: relative;
    margin-bottom: 10px;
}
div[class^='button'] { position: absolute; }
.button_up, .button_down { width:214px; height:104px;}
.button_left, .button_right { width:104px; height:214px;}
.button_stop { width:178px; height:178px;}
.button_up {
    background: url('https://newbiely.com/images/tutorial/up_inactive.png') no-repeat; 
  background-size: contain; 
    left: 200px;
    top: 0px;
  transform: translateX(-50%);
}

.button_down {
    background: url('https://newbiely.com/images/tutorial/down_inactive.png') no-repeat; 
  background-size: contain; 
    left:200px;
    bottom: 0px;
  transform: translateX(-50%);
}

.button_right {
    background: url('https://newbiely.com/images/tutorial/right_inactive.png') no-repeat;
  background-size: contain;   
    right: 0px;
    top: 200px;
  transform: translateY(-50%);
}

.button_left {
    background: url('https://newbiely.com/images/tutorial/left_inactive.png') no-repeat; 
  background-size: contain;
    left:0px;
    top: 200px;
  transform: translateY(-50%);
}

.button_stop {
  background: url('https://newbiely.com/images/tutorial/stop_inactive.png') no-repeat; 
  background-size: contain;
    left:200px;
    top: 200px;
  transform: translate(-50%, -50%);
}
</style>
<script>
var CMD_STOP     = 0;
var CMD_FORWARD  = 1;
var CMD_BACKWARD = 2;
var CMD_LEFT     = 4;
var CMD_RIGHT    = 8;
var img_name_lookup = {
  [CMD_STOP]:     "stop",
  [CMD_FORWARD]:  "up",
  [CMD_BACKWARD]: "down",
  [CMD_LEFT]:     "left",
  [CMD_RIGHT]:    "right"
}
var ws = null;

function init() 
{
  
  var container = document.querySelector("#container");
    container.addEventListener("touchstart", mouse_down);
    container.addEventListener("touchend", mouse_up);
    container.addEventListener("touchcancel", mouse_up);
    container.addEventListener("mousedown", mouse_down);
    container.addEventListener("mouseup", mouse_up);
    container.addEventListener("mouseout", mouse_up);    
}
function ws_onmessage(e_msg)
{
    e_msg = e_msg || window.event; // MessageEvent
 
    //alert("msg : " + e_msg.data);
}
function ws_onopen()
{
  document.getElementById("ws_state").innerHTML = "OPEN";
  document.getElementById("wc_conn").innerHTML = "Disconnect";
}
function ws_onclose()
{
  document.getElementById("ws_state").innerHTML = "CLOSED";
  document.getElementById("wc_conn").innerHTML = "Connect";
  console.log("socket was closed");
  ws.onopen = null;
  ws.onclose = null;
  ws.onmessage = null;
  ws = null;
}
function wc_onclick()
{
  if(ws == null)
  {
    ws = new WebSocket("ws://" + window.location.host + ":81");
    document.getElementById("ws_state").innerHTML = "CONNECTING";
    
    ws.onopen = ws_onopen;
    ws.onclose = ws_onclose;
    ws.onmessage = ws_onmessage; 
  }
  else
    ws.close();
}
function mouse_down(event) 
{
  if (event.target !== event.currentTarget) 
  {
    var id = event.target.id;
    send_command(id);
    event.target.style.backgroundImage = "url('https://newbiely.com/images/tutorial/" + img_name_lookup[id] + "_active.png')";
    }
    event.stopPropagation();    
    event.preventDefault();    
}

function mouse_up(event) 
{
  if (event.target !== event.currentTarget) 
  {
    var id = event.target.id;
    send_command(CMD_STOP);
    event.target.style.backgroundImage = "url('https://newbiely.com/images/tutorial/" + img_name_lookup[id] + "_inactive.png')";
    }
    event.stopPropagation();   
    event.preventDefault();    
}
function send_command(cmd) 
{   
  if(ws != null)
    if(ws.readyState == 1)
      ws.send(cmd + "\r\n");   
}

window.onload = init;
</script>
</head>
<body>
<h2>ESP8266 - RC Car via Web</h2>
<div id="container">
  <div id="0" class="button_stop"></div>
    <div id="1" class="button_up"></div>
    <div id="2" class="button_down"></div>
    <div id="8" class="button_right"></div>
    <div id="4" class="button_left"></div>
</div>
<p>
WebSocket : <span id="ws_state" style="color:blue">closed</span><br>
</p>
<button id="wc_conn" type="button" onclick="wc_onclick();">Connect</button>
<br>
<br>
<div class="sponsor">Sponsored by <a href="https://amazon.com/diyables">DIYables</a></div>
</body>
</html>
)=====";

Now go to mobile browser connect to same network given in the code.
Get the IP of the NodeMCU and input it in browser as URL.
Quick Summary video below




Comments

Post a Comment

Popular posts from this blog

Microphone Sound Sensor explained | HW-484 | Interfacing with ESP 8266

Image
 Microphone Sound Sensor In this tutorial, we will learn about microphone sound sensor which is used to measure sound intensity. The sensor takes in ambient sound and provides a voltage corresponding to intensity in both digital and analog outputs. We will see both cases of outputs. Case 1 : Using Digital Output In this we will try to lit an Led if the voltage output is above a threshold. Parts Needed 1. ESP 8266 NodeMCU 2. 330 Ohms resistor 4. HW 484 Sensor 5. Power supply 3.3v/5v 6. Led  7. Jumper wires and bread board Connections Power supply 3.3V - HW484 + Power supply Gnd - HW484 G NodeMCU D4 - HW484 D0 NodeMCU D2 - 330 Ohms Resistor - Led CODE boolean soundValue = 0 ; void setup ( ) {   pinMode ( D2 , OUTPUT ) ;   pinMode ( D4 , INPUT ) ;   Serial . begin ( 115200 ) ; } void loop ( ) {   soundValue = digitalRead ( D4 ) ;   Serial . println ( soundValue ) ;   if ( soundValue == HIGH ) {     di...
Read more

Using ESP 01 in Access Point (AP) mode to control ESP relay switch | ESP wifi tutorial | Part - 1

Image
Control ESP relay switch using wifi access point on ESP 01 In the last tutorial , we have seen how to control relay using ESP 01 as micro controller. In this tutorial, i will attempt to introduce ESP relay switch designed to work seamlessly with ESP 01.  we will also control the relay in built wifi capability of ESP 01. We will attempt to use Access Point (AP) Mode which allows devices like mobile, laptop and other esps to connect to wifi network created by esp. This mode can be used to create a local network to control and communicate between master and slave nodes. We will setup a web server on ESP 01, use it to change relay state on a android mobile. ESP Relay Switch This is a relay switch with inbuilt slot for ESP 01. It has 5v and GND terminal to power relay and ESP 01. It has NC, COM and NO terminal to collect output of the relay. ESP relay switch front and back view. Hardware requirements 1. ESP relay switch. 2. Multi output voltage converter power module 3. Led Strip connec...
Read more